# Maintainer: Markus Fritsche <mfritsche@reauktion.de>
# sic daemon — netstring-framed argv over stdin, execvp'd. Deploy on target hosts.
# Source of truth: git.reauktion.de/marfrit/sic

pkgname=sicd
pkgver=0.2.0
pkgrel=1
pkgdesc="sic daemon: reads netstring-framed argv from stdin and execvp's it (deploy on remote/target hosts)"
arch=('x86_64' 'aarch64')
url="https://git.reauktion.de/marfrit/sic"
license=('MIT')
makedepends=('go')
optdepends=('openssh: run sicd as an ssh ForceCommand / authorized_keys command')
source=("sic-${pkgver}.tar.gz::https://git.reauktion.de/marfrit/sic/archive/v${pkgver}.tar.gz")
sha256sums=('fe0569013da5bfa248743cd04bc2f09da8217b04432aa69827ed5287a133a37c')

build() {
    cd "${srcdir}/sic"
    case "$CARCH" in
        x86_64)  export GOARCH=amd64 ;;
        aarch64) export GOARCH=arm64 ;;
    esac
    export GOOS=linux CGO_ENABLED=0 GOFLAGS='-buildvcs=false -trimpath'
    go build -ldflags='-s -w' -o sicd ./cmd/sicd
}

package() {
    cd "${srcdir}/sic"
    install -Dm755 sicd           "${pkgdir}/usr/bin/sicd"
    install -Dm644 gateway/sicd   "${pkgdir}/usr/share/doc/${pkgname}/sicd-reference.py"
    install -Dm644 docs/design.md "${pkgdir}/usr/share/doc/${pkgname}/design.md"
    install -Dm644 LICENSE        "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}