marfrit-packages/arch/ffmpeg-v4l2-request-git/PKGBUILD

# Maintainer: Markus Fritsche <mfritsche@reauktion.de>
#
# FFmpeg + V4L2-Request hwaccel (stateless video decode on Rockchip,
# Allwinner, etc) for the Fourier umbrella. Tracks Kwiboo's long-running
# rebase of Jernej Škrabec's v4l2-request patchset onto ffmpeg release
# tags. Pins the branch tip to a known commit for reproducible CI builds;
# bump _commit when upstream picks up a fix we want.
#
# Why this fork instead of AUR ffmpeg-v4l2-request-git:
#  - AUR is pinned to 6.1.1 with epoch=2, which is OLDER than Arch's
#    stock 2:8.1-3 → installing it downgrades system ffmpeg.
#  - AUR pulls X11/AMF/CUDA/FireWire/AviSynth/OpenMPT/Bluray — irrelevant
#    for a Wayland + ARM + video-decode fleet.
#  - AUR uses #branch=..., no commit pin. CI artifacts are non-reproducible.
#
# Encoders (libx264/libx265/libvpx/libdav1d) kept per Fourier fleet policy.
# X11, AMF, CUDA, FireWire, AviSynth, OpenMPT, Bluray, OpenMAX, JPEG-XL,
# Theora, XVid, rsvg, soxr, ssh, vidstab, modplug, SDL2, Vulkan, JACK, GSM,
# Speex dropped — not needed on the Fourier fleet. (No SDL2 means no
# `ffplay` binary; mpv covers interactive playback.)

pkgname=ffmpeg-v4l2-request-fourier
_srcname=FFmpeg
_version='8.1'
_commit='b57fbbe50c9b2656fad86a1a7eeabfd2b2a50935'  # v4l2-request-n8.1 tip 2026-04-24
pkgver=8.1.r123329.b57fbbe
pkgrel=4
epoch=2
pkgdesc='FFmpeg with V4L2 Request API hwaccel (Rockchip / Allwinner stateless decode)'
arch=('aarch64')
url='https://github.com/Kwiboo/FFmpeg'
license=('GPL-3.0-or-later')
depends=(
  alsa-lib
  bzip2
  fontconfig
  fribidi
  gmp
  gnutls
  lame
  libass.so
  libdav1d.so
  libdrm
  libfreetype.so
  libgl
  libpulse
  libva.so
  libva-drm.so
  libvorbis.so
  libvorbisenc.so
  libvpx.so
  libwebp
  libx264.so
  libx265.so
  libxml2
  opus
  v4l-utils
  xz
  zlib
)
makedepends=(
  git
  linux-api-headers
  mesa
  nasm
)
provides=(
  libavcodec.so
  libavdevice.so
  libavfilter.so
  libavformat.so
  libavutil.so
  libpostproc.so
  libswresample.so
  libswscale.so
  ffmpeg
)
conflicts=(ffmpeg)
replaces=(ffmpeg ffmpeg-v4l2-request-git)
source=("git+https://github.com/Kwiboo/FFmpeg.git#commit=${_commit}"
        '0001-libudev-bypass-fallback.patch')
sha256sums=('SKIP' 'SKIP')

pkgver() {
  cd "${_srcname}"
  printf '%s.r%s.%s' "${_version}" \
    "$(git rev-list --count HEAD)" \
    "$(git rev-parse --short=7 HEAD)"
}

prepare() {
  cd "${_srcname}"
  patch -Np1 -i "${srcdir}/0001-libudev-bypass-fallback.patch"
}

build() {
  cd "${_srcname}"

  # FFmpeg's configure resolves the compiler via `which` and bakes the
  # absolute path into generated makefiles, bypassing the makepkg
  # /usr/lib/distcc/bin shim. Pass it explicitly so `BUILDENV=(distcc ...)`
  # actually distributes; otherwise everything compiles locally.
  local _ffmpeg_cc=gcc _ffmpeg_cxx=g++
  if [[ ":$PATH:" == *":/usr/lib/distcc/bin:"* ]]; then
    _ffmpeg_cc='distcc gcc'
    _ffmpeg_cxx='distcc g++'
  fi

  ./configure \
    --prefix=/usr \
    --cc="${_ffmpeg_cc}" \
    --cxx="${_ffmpeg_cxx}" \
    --disable-debug \
    --disable-static \
    --disable-doc \
    --disable-stripping \
    --enable-shared \
    --enable-gpl \
    --enable-version3 \
    --enable-pic \
    --enable-neon \
    --arch=aarch64 \
    \
    --enable-libdrm \
    --enable-libv4l2 \
    --enable-libudev \
    --enable-v4l2-request \
    --enable-v4l2_m2m \
    --enable-vaapi \
    --enable-opengl \
    \
    --enable-gnutls \
    --enable-fontconfig \
    --enable-libass \
    --enable-libfreetype \
    --enable-libfribidi \
    --enable-libxml2 \
    --enable-libpulse \
    --enable-libdav1d \
    --enable-libopus \
    --enable-libvorbis \
    --enable-libmp3lame \
    --enable-libvpx \
    --enable-libx264 \
    --enable-libx265 \
    --enable-libwebp \
    \
    --host-cflags='-fPIC'

  make
  make tools/qt-faststart
}

package() {
  cd "${_srcname}"
  make DESTDIR="${pkgdir}" install
  install -Dm755 tools/qt-faststart "${pkgdir}/usr/bin/qt-faststart"
}